DroidFS/app/build.gradle

apply plugin: 'com.android.application'
apply plugin: 'kotlin-android'

android {
    compileSdkVersion 31
    buildToolsVersion "31"
    ndkVersion "23.0.7599858"

    compileOptions {
        targetCompatibility JavaVersion.VERSION_1_8
    }

    defaultConfig {
        applicationId "sushi.hardcore.droidfs"
        minSdkVersion 21
        targetSdkVersion 29
        versionCode 19
        versionName "1.6.0"

        ndk {
            abiFilters "x86", "x86_64", "armeabi-v7a", "arm64-v8a"
        }
    }

    if (!file("fdroid").exists()) {
        splits {
            abi {
                enable true
                universalApk true
            }
        }
    }

    applicationVariants.all { variant ->
        variant.resValue "string", "versionName", variant.versionName
    }

    buildFeatures {
        viewBinding true
    }

    buildTypes {
        release {
            minifyEnabled true
            shrinkResources true
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }

    externalNativeBuild {
        cmake {
            path file('CMakeLists.txt')
        }
    }
}

dependencies {
    implementation fileTree(dir: "libs", include: ["*.jar"])
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8:$kotlin_version"
    implementation 'androidx.core:core-ktx:1.7.0'
    implementation "androidx.appcompat:appcompat:1.3.1"
    implementation "androidx.constraintlayout:constraintlayout:2.1.1"

    implementation "androidx.sqlite:sqlite-ktx:2.1.0"
    implementation "androidx.preference:preference-ktx:1.1.1"
    implementation "androidx.swiperefreshlayout:swiperefreshlayout:1.1.0"
    implementation 'com.google.android.material:material:1.4.0'
    implementation "com.github.bumptech.glide:glide:4.12.0"
    implementation "androidx.biometric:biometric:1.1.0"

    def exoplayer_version = "2.16.0"
    implementation "com.google.android.exoplayer:exoplayer-core:$exoplayer_version"
    implementation "com.google.android.exoplayer:exoplayer-ui:$exoplayer_version"

    implementation "androidx.concurrent:concurrent-futures:1.1.0"

    def camerax_v1 = "1.1.0-alpha10"
    implementation "androidx.camera:camera-camera2:$camerax_v1"
    implementation "androidx.camera:camera-lifecycle:$camerax_v1"
    def camerax_v2 = "1.0.0-alpha30"
    implementation "androidx.camera:camera-view:$camerax_v2"
    implementation "androidx.camera:camera-extensions:$camerax_v2"
}