; The OS/K Team licenses this file to you under the MIT license.
; See the LICENSE file in the project root for more information.

;
; void itoa(char *buf, int num, int base)
;
itoa:
    mov ax3, 1
    jmp ltostr

;
; void utoa(char *buf, int num, int base)
;
utoa:
    sub ax3, ax3
    jmp ltostr

;
; void ltostr(char *buf, int num, int base, bool signed)
;
ltostr:
    mov rax, ax0
    xor rx8, rx8

    ; make sure base is in [2, 32]
    cmp ax2, 2
    j.b .bad
    cmp ax2, 36
    j.a .bad

    ; deal with zero
    test ax1, ax1
    j.z .zero

    ; deal with base 10 signedness

    test ax3, ax3
    cmp.nz ax2, 10     ; base 10
    j.nz .conv

    sgn rx8, ax1    ; extract ax1 sign

    cmp rx8, -1     ; negative?
    neg.z ax1

    ; main loop
.conv:
    test ax1, ax1
    j.z .fini

    mov r10, ax1
    rem r10, ax2    ; ax1 % base

    cmp r10, 9      ; r10 > 9 ?
    j.a .nondec

    add r10, '0'
    jmp .next

.nondec:
    add r10, 55     ; 'A' - 10

.next:
    mov b[ax0], r10
    inc ax0

    div ax1, ax2
    jmp .conv

    ; add minus flag, null-terminate and reverse
.fini:
    cmp rx8, -1
    mov.z b[ax0], '-'
    inc.z ax0

    mov b[ax0], 0

    mov ax0, rax
    call strrev2

    ret

;
; exceptional cases
;
.bad:
    mov q[errno], EINVAL
    mov b[ax0], 0
    ret

.zero:
    mov b[ax0], 48   ; '0'
    mov b[ax0+1], 0
    ret