XSLT_TAO/filtres_TMX_pour_Calc/TMX-import.xsl

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<!-- Dominique Meeùs, created 30-9-2013, version 0.9.
     XSLT transformation of a TMX translation memory exchange file
     into an Open Document Format spreadsheet in two columns.
     Filter to install as an import filter for LibreOffice Calc. -->
<!-- Philippe Tourigny, modified 12-9-2022, version 0.95
     Allow the filter to retrieve the languages in the TMX from its
     first <tu> element, and create a column for each language. -->
<!-- Philippe Tourigny, modified 3-6-2023, version 0.96
     Streamline namespaces to only those used in the transformation. -->     
<!-- Copyright 2013 Dominique Meeùs, and 2022 Philippe Tourigny.
     This program is free software: you can redistribute it and/or modify it
     under the terms of the GNU Lesser General Public License
     as published by the Free Software Foundation,
     either version 3 of the License, or (at your option) any later version.
     This program is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY;
     without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
     See the GNU Lesser General Public License for more details.
     You should have received a copy of the GNU Lesser General Public License along with this program.
     If not, see http://www.gnu.org/licenses/. -->
  <xsl:template match="/">
    <office:document-content
      xmlns:office="urn:oasis:names:tc:opendocument:xmlns:office:1.0"
      xmlns:style="urn:oasis:names:tc:opendocument:xmlns:style:1.0"
      xmlns:text="urn:oasis:names:tc:opendocument:xmlns:text:1.0"
      xmlns:table="urn:oasis:names:tc:opendocument:xmlns:table:1.0"
      xmlns:fo="urn:oasis:names:tc:opendocument:xmlns:xsl-fo-compatible:1.0"      
      office:version="1.0">

      <office:automatic-styles>
        <!-- PTable properties -->
        <style:style style:name="ta1" style:family="table" style:master-page-name="Default">
          <style:table-properties table:display="true" style:writing-mode="lr-tb"/>
        </style:style>

        <!-- Column properties (for all languages) -->
        <style:style style:name="co1" style:family="table-column">
          <style:table-column-properties fo:break-before="auto" style:column-width="14.000cm"/>
        </style:style>

        <!-- Row properties -->
        <!-- All rows are set to “optimal height” -->
        <style:style style:name="ro1" style:family="table-row">
          <style:table-row-properties fo:break-before="auto" style:use-optimal-row-height="true"/>
        </style:style>

        <!-- Cell properties -->
        <!-- Language code heading cells
             The language codes are centered and set in bold
             in the first column. -->
        <style:style style:name="heading" style:family="table-cell"
          style:parent-style-name="Default">
          <style:table-cell-properties style:text-align-source="fix"
            style:repeat-content="false" fo:wrap-option="wrap"/>
          <style:paragraph-properties fo:text-align="center"/>
          <style:text-properties fo:font-weight="bold"/>
        </style:style>

        <!-- Style for cells with the segment text -->
        <style:style style:name="ce2" style:family="table-cell" style:parent-style-name="Default">
          <style:table-cell-properties fo:wrap-option="wrap"/>
        </style:style>
      </office:automatic-styles>

      <!-- Define variables used to identify the languages
           In a TMX with three or more languages. All translation unit
           (<tuv>) elements are assumed to contain the same number of
           languages, and the first <tu> is used to identify them. -->
      
      <!-- Todo: Identify the <tu> with the largest highest number of <tuv> elements to identify all languages in a TMX file with more languages in some <tu> elements than others. -->
      <xsl:variable name="firstTU" select="tmx/body/tu[1]"/>
      <xsl:variable name="numLangs" select="count($firstTU/tuv)"/>

      <office:body>
        <office:spreadsheet>
            <table:table table:style-name="ta1">
            <!-- Set the format for a number of columns equal to
                 the number of languages in the imported TMX file -->
            <table:table-column table:style-name="co1" table:number-columns-repeated="{$numLangs}"
                  table:default-cell-style-name="ce2"/>

                <!-- Fill in the language headers in the first row
                     The use of the "local-name()" function enables
                     the filter to handle older versions that use the
                     "lang" attribute as well as recent versions that
                     use the "xml:lang"` attributes -->
                <table:table-row table:style-name="ro1">
                  <xsl:for-each select="$firstTU/tuv">
                    <table:table-cell table:style-name="heading">
                <text:p>
                        <xsl:value-of select="@*[local-name()='lang']"/>
                </text:p>
              </table:table-cell>
                  </xsl:for-each> 
            </table:table-row>

                <!-- Process the <tu> and <tuv> elements in the TMX file:
                     One row per tu, one column per segment in each <tuv>. -->
            <xsl:for-each select="tmx/body/tu">
              <table:table-row  table:style-name="ro1">
                <xsl:for-each select="tuv">
                  <table:table-cell>
                    <text:p><xsl:value-of select="seg"/></text:p>
                  </table:table-cell>
                </xsl:for-each>
              </table:table-row>
            </xsl:for-each>
          </table:table>
        </office:spreadsheet>
      </office:body>
    </office:document-content>
  </xsl:template>
</xsl:stylesheet>